Database monitor logical table 3021 - Summary Row for Bitmap Created

|...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....8
     A*
     A* DB Monitor logical table 3021 - Summary Row for Bitmap Created
     A* 
     A* New row added for Visual Explain
     A*
     A          R QQQ3021                   PTABLE(*CURLIB/QAQQDBMN) 
     A            QQRID 
     A            QQTIME 
     A            QQJFLD 
     A            QQRDBN 
     A            QQSYS 
     A            QQJOB 
     A            QQUSER 
     A            QQJNUM 
     A            QQTHRD                    RENAME(QQI9) + 
                                            COLHDG('Thread' + 
                                                   'Identifier') 
     A            QQUCNT 
     A            QQUDEF 
     A            QQQDTN 
     A            QQQDTL 
     A            QQMATN 
     A            QQMATL
     A            QVRCNT
     A            QVPARPF
     A            QVPARPL 
     A            QVPARD        
     A            QVPARU        
     A            QVPARRC
     A            QQEPT
     A            QVCTIM
     A            QQREST
     A            QQAJN
     A            QQJNP 
     A            QQJNDS                    RENAME(QQI6) + 
                                            COLHDG('Data Space' +
                                                   'Number') 
     A            QQJNMT                    RENAME(QQC21) + 
                                            COLHDG('Join' 'Method') 
     A            QQJNTY                    RENAME(QQC22) + 
                                            COLHDG('Join' 'Type') 
     A            QQJNOP                    RENAME(QQC23) + 
                                            COLHDG('Join' 'Operator')
     A            QVJFANO
     A            QVFILES                
     A            QVBMSIZ                   RENAME(QQI2) + 
                                            COLHDG('Bitmap' +
                                                   'Size')
     A            QVBMCNT                   RENAME(QVP151) + 
                                            COLHDG('Number of' +
                                                   'Bitmaps'
                                                   'Created')
     A            QVBMIDS                   RENAME(QVC3001) + 
                                            COLHDG('Internal' +
                                                   'Bitmap' 'IDs')
     A          K QQJFLD 
     A          S QQRID                     CMP(EQ 3021) 

Table 26. QQQ3021 - Summary Row for Bitmap Created

Logical Column Name	Physical Column Name	Description
QQRID	QQRID	Row identification
QQTIME	QQTIME	Time row was created
QQJFLD	QQJFLD	Join column (unique per job)
QQRDBN	QQRDBN	Relational database name
QQSYS	QQSYS	System name
QQJOB	QQJOB	Job name
QQUSER	QQUSER	Job user
QQJNUM	QQJNUM	Job number
QQTHRD	QQI9	Thread identifier
QQUCNT	QQUCNT	Unique count (unique per query)
QQUDEF	QQUDEF	User defined column
QQQDTN	QQQDTN	Unique subselect number
QQQDTL	QQQDTL	Subselect nested level
QQMATN	QQMATN	Materialized view subselect number
QQMATL	QQMATL	Materialized view nested level
QVRCNT	QVRCNT	Unique refresh counter
QVPARPF	QVPARPF	Parallel Prefetch (Y/N)
QVPARPL	QVPARPL	Parallel Preload (index used)
QVPARD	QVPARD	Parallel degree requested (index used)
QVPARU	QVPARU	Parallel degree used (index used)
QVPARRC	QVPARRC	Reason parallel processing was limited (index used)
QQEPT	QQEPT	Estimated processing time, in seconds
QVCTIM	QVCTIM	Estimated cumulative time, in seconds
QQREST	QQREST	Estimated rows selected
QQAJN	QQAJN	Estimated number of joined rows
QQJNP	QQJNP	Join position - when available
QQJNDS	QQI6	Data space number/Original table position
QQJNMT	QQC21	Join method - when available NL - Nested loop MF - Nested loop with selection HJ - Hash join
QQJNTY	QQC22	Join type - when available IN - Inner join PO - Left partial outer join EX - Exception join
QQJNOP	QQC23	Join operator - when available EQ - Equal NE - Not equal GT - Greater than GE - Greater than or equal LT - Less than LE - Less than or equal CP - Cartesian product
QVJFANO	QVJFANO	Join fan out. Possible values are: N - Normal join situation where fanout is allowed and each matching row of the join fanout is returned. D - Distinct fanout. Join fanout is allowed however none of the join fanout rows are returned. U - Unique fanout. Join fanout is not allowed. Error situation if join fanout occurs.
QVFILES	QVFILES	Number of tables joined
QVBMSIZ	QQI2	Bitmap size
QVBMCNT	QVP151	Number of bitmaps created
QVBMIDS	QVC3001	Internal bitmap IDs