Database monitor logical table 3007 - Summary Row for Optimizer Timed Out

|...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....8
     A*
     A* DB Monitor logical table 3007 - Summary Row for Optimizer Timed Out 
     A* 
     A          R QQQ3007                   PTABLE(*CURLIB/QAQQDBMN) 
     A            QQRID 
     A            QQTIME 
     A            QQJFLD 
     A            QQRDBN 
     A            QQSYS 
     A            QQJOB 
     A            QQUSER 
     A            QQJNUM 
     A            QQTHRD                    RENAME(QQI9) + 
                                            COLHDG('Thread' + 
                                                   'Identifier') 
     A            QQUCNT 
     A            QQUDEF 
     A            QQQDTN 
     A            QQQDTL 
     A            QQMATN 
     A            QQMATL 
     A            QQTLN 
     A            QQTFN 
     A            QQTMN 
     A            QQPTLN 
     A            QQPTFN 
     A            QQPTMN 
     A            QQIDXN                    RENAME(QQ1000) + 
                                            COLHDG('Index' + 
                                                   'Names') 
     A            QQTOUT                    RENAME(QQC11) + 
                                            COLHDG('Optimizer' + 
                                                   'Timed Out')
     A            QQISRN                    RENAME(QQC301) + 
                                            COLHDG('Index' + 
                                                   'Reason' +
                                                   'Codes')
     A* 
     A* Columns added for Visual Explain
     A*
     A            QVQTBL 
     A            QVQLIB
     A            QVPTBL
     A            QVPLIB
     A            QQJNP 
     A            QQJNDS                    RENAME(QQI6) + 
                                            COLHDG('Data Space' +
                                                   'Number') 
     A            QQJNMT                    RENAME(QQC21) + 
                                            COLHDG('Join' 'Method') 
     A            QQJNTY                    RENAME(QQC22) + 
                                            COLHDG('Join' 'Type') 
     A            QQJNOP                    RENAME(QQC23) + 
                                            COLHDG('Join' 'Operator')
     A            QVJFANO
     A            QVFILES
     A            QVRCNT
     A          K QQJFLD 
     A          S QQRID                     CMP(EQ 3007) 

Table 20. QQQ3007 - Summary Row for Optimizer Timed Out

Logical Column Name	Physical Column Name	Description
QQRID	QQRID	Row identification
QQTIME	QQTIME	Time row was created
QQJFLD	QQJFLD	Join column (unique per job)
QQRDBN	QQRDBN	Relational database name
QQSYS	QQSYS	System name
QQJOB	QQJOB	Job name
QQUSER	QQUSER	Job user
QQJNUM	QQJNUM	Job number
QQTHRD	QQI9	Thread identifier
QQUCNT	QQUCNT	Unique count (unique per query)
QQUDEF	QQUDEF	User defined column
QQQDTN	QQQDTN	Unique subselect number
QQQDTL	QQQDTL	Subselect nested level
QQMATN	QQMATN	Materialized view subselect number
QQMATL	QQMATL	Materialized view nested level
QQTLN	QQTLN	Library of table queried
QQTFN	QQTFN	Name of table queried
QQTMN	QQTMN	Member name of table queried
QQPTLN	QQPTLN	Library name of base table
QQPTFN	QQPTFN	Name of base table for table queried
QQPTMN	QQPTMN	Member name of base table
QQIDXN	QQ1000	Index names
QQTOUT	QQC11	Optimizer timed out Y - Yes N - No
QQISRN	QQC301	List of unique reason codes used by the indexes that timed out (each index has a corresponding reason code associated with it)
QVQTBL	QVQTBL	Queried table, long name
QVQLIB	QVQLIB	Library of queried table, long name
QVPTBL	QVPTBL	Base table, long name
QVPLIB	QVPLIB	Library of base table, long name
QQJNP	QQJNP	Join position - when available
QQJNDS	QQI6	Data space number
QQJNMT	QQC21	Join method - when available NL - Nested loop MF - Nested loop with selection HJ - Hash join
QQJNTY	QQC22	Join type - when available IN - Inner join PO - Left partial outer join EX - Exception join
QQJNOP	QQC23	Join operator - when available EQ - Equal NE - Not equal GT - Greater than GE - Greater than or equal LT - Less than LE - Less than or equal CP - Cartesian product
QVJFANO	QVJFANO	Join fan out. Possible values are: N - Normal join situation where fanout is allowed and each matching row of the join fanout is returned. D - Distinct fanout. Join fanout is allowed however none of the join fanout rows are returned. U - Unique fanout. Join fanout is not allowed. Error situation if join fanout occurs.
QVFILES	QVFILES	Number of tables joined
QVRCNT	QVRCNT	Unique refresh counter